Robotics / Embedded Control / Mechatronics

Articulated Robotic Arm

A servo-driven robotic arm project focused on mechanical assembly, embedded control, gripper actuation, and real-time motion testing through Arduino-based firmware.

Project Overview

The Articulated Robotic Arm is a compact servo-driven mechatronics project built around an Arduino Uno, a PCA9685 servo motor driver, MG996R servo motors, a servo base chassis, and a mechanical gripper. The system demonstrates coordinated multi-axis robotic motion using embedded control commands to drive the base, arm joints, and end-effector.

The project focuses on practical robotic system integration, including servo calibration, PWM signal control, wiring organization, joint motion testing, and gripper actuation. Each servo is controlled through the PCA9685 driver, allowing the Arduino Uno to command multiple joints while keeping the wiring and control architecture organized.

Core Discipline

Robotics, embedded control, servo actuation, mechanical assembly, and mechatronics integration.

Control Hardware

Arduino Uno microcontroller paired with a PCA9685 PWM servo motor driver for multi-servo control.

Design Focus

Coordinated joint movement, stable servo positioning, gripper control, and repeatable robotic motion.

Bill of Materials

Main hardware components used to assemble and control the articulated robotic arm.

Item	Component	Quantity	Function
01	MG996R 55g Servo Motors	4	Provides joint actuation for arm movement and positioning.
02	PCA9685 Servo Motor Driver	1	Generates PWM signals for controlling multiple servo channels.
03	Arduino Uno Microcontroller	1	Runs the control logic and sends commands to the servo driver.
04	Servo Base Chassis	1	Supports the robotic arm structure and houses the base rotation assembly.
05	Mechanical Gripper	1	Acts as the end-effector for grabbing, holding, and releasing objects.

Functional Demo

Robotic Arm in Operation

A short demonstration showing the articulated robotic arm responding to servo control commands, moving through multiple joints, and actuating the mechanical gripper.

Manufacturing Document

Manufacturing Document - GD&T

Engineering drawing package for the servo base chassis, including dimensional controls, datum references, and GD&T documentation used to define the manufactured geometry.

Servo base chassis manufacturing drawing with GD&T

Articulated Robotic Arm Firmware Preview

// Articulated Robotic Arm Firmware Preview
// JDESIGNLABS Portfolio Project
// Servo-based multi-axis robotic arm with gripper control

#include <Arduino.h>
#include <Wire.h>
#include <Adafruit_PWMServoDriver.h>

Adafruit_PWMServoDriver pwm = Adafruit_PWMServoDriver(0x40, Wire);

#define SERVOMIN_PAN     107
#define SERVOMAX_PAN     437

#define SERVOMIN_TILT    90
#define SERVOMAX_TILT    380

#define SERVOMIN_ROLL    90
#define SERVOMAX_ROLL    356

#define SERVOMIN_TILT_2  90
#define SERVOMAX_TILT_2  500

#define SERVOMIN_ROLL_2  90
#define SERVOMAX_ROLL_2  500

#define SERVOMIN_CRUNCH  0
#define SERVOMAX_CRUNCH  400

#define USMIN       600
#define USMAX       2400
#define SERVO_FREQ  50

#define PAN_PIN      0
#define TILT_PIN     1
#define ROLL_PIN     2
#define CRUNCH_PIN   3
#define TILT_PIN_2   4
#define ROLL_PIN_2   5

#define SERVO_STEP 10

int16_t panPos     = 270;
int16_t tiltPos    = 150;
int16_t rollPos    = 150;
int16_t crunchPos  = 90;
int16_t tiltPos2   = 150;
int16_t rollPos2   = 150;

void printHelp();
void printPositions();
void setServoPulse(uint8_t n, double pulse);
void setAllServos();
void homePosition();

void setup() {
  Serial.begin(9600);

while (!Serial) {
    delay(10);
  }

Serial.println("Articulated Robotic Arm Servo Control");
  Serial.println("PCA9685 6-channel servo test");

pwm.begin();
  pwm.setOscillatorFrequency(27000000);
  pwm.setPWMFreq(SERVO_FREQ);

delay(10);

panPos    = constrain(panPos, SERVOMIN_PAN, SERVOMAX_PAN);
  tiltPos   = constrain(tiltPos, SERVOMIN_TILT, SERVOMAX_TILT);
  rollPos   = constrain(rollPos, SERVOMIN_ROLL, SERVOMAX_ROLL);
  tiltPos2  = constrain(tiltPos2, SERVOMIN_TILT_2, SERVOMAX_TILT_2);
  rollPos2  = constrain(rollPos2, SERVOMIN_ROLL_2, SERVOMAX_ROLL_2);
  crunchPos = constrain(crunchPos, SERVOMIN_CRUNCH, SERVOMAX_CRUNCH);

setAllServos();

printHelp();
  printPositions();
}

void loop() {
  if (Serial.available() > 0) {
    char input = Serial.read();

if (input == '\n' || input == '\r') {
      return;
    }

switch (input) {
      case 'a':
      case 'd': {
        panPos += (input == 'a') ? SERVO_STEP : -SERVO_STEP;
        panPos = constrain(panPos, SERVOMIN_PAN, SERVOMAX_PAN);
        pwm.setPWM(PAN_PIN, 0, panPos);

Serial.print("panPos = ");
        Serial.println(panPos);
        break;
      }

case 'r':
      case 'f': {
        tiltPos += (input == 'r') ? SERVO_STEP : -SERVO_STEP;
        tiltPos = constrain(tiltPos, SERVOMIN_TILT, SERVOMAX_TILT);
        pwm.setPWM(TILT_PIN, 0, tiltPos);

Serial.print("tiltPos = ");
        Serial.println(tiltPos);
        break;
      }

case 'q':
      case 'e': {
        rollPos += (input == 'q') ? SERVO_STEP : -SERVO_STEP;
        rollPos = constrain(rollPos, SERVOMIN_ROLL, SERVOMAX_ROLL);
        pwm.setPWM(ROLL_PIN, 0, rollPos);

Serial.print("rollPos = ");
        Serial.println(rollPos);
        break;
      }

case 'w':
      case 's': {
        crunchPos += (input == 'w') ? SERVO_STEP : -SERVO_STEP;
        crunchPos = constrain(crunchPos, SERVOMIN_CRUNCH, SERVOMAX_CRUNCH);
        pwm.setPWM(CRUNCH_PIN, 0, crunchPos);

Serial.print("crunchPos = ");
        Serial.println(crunchPos);
        break;
      }

case 't':
      case 'g': {
        tiltPos2 += (input == 't') ? SERVO_STEP : -SERVO_STEP;
        tiltPos2 = constrain(tiltPos2, SERVOMIN_TILT_2, SERVOMAX_TILT_2);
        pwm.setPWM(TILT_PIN_2, 0, tiltPos2);

Serial.print("tiltPos2 = ");
        Serial.println(tiltPos2);
        break;
      }

case 'y':
      case 'h': {
        rollPos2 += (input == 'y') ? SERVO_STEP : -SERVO_STEP;
        rollPos2 = constrain(rollPos2, SERVOMIN_ROLL_2, SERVOMAX_ROLL_2);
        pwm.setPWM(ROLL_PIN_2, 0, rollPos2);

Serial.print("rollPos2 = ");
        Serial.println(rollPos2);
        break;
      }

case 'x': {
        homePosition();
        Serial.println("Moved to home position.");
        printPositions();
        break;
      }

case 'p': {
        printPositions();
        break;
      }

case '?': {
        printHelp();
        break;
      }

default: {
        Serial.print("Unknown command: ");
        Serial.println(input);
        Serial.println("Type ? for command list.");
        break;
      }
    }
  }
}

void setAllServos() {
  pwm.setPWM(PAN_PIN, 0, panPos);
  pwm.setPWM(TILT_PIN, 0, tiltPos);
  pwm.setPWM(ROLL_PIN, 0, rollPos);
  pwm.setPWM(CRUNCH_PIN, 0, crunchPos);
  pwm.setPWM(TILT_PIN_2, 0, tiltPos2);
  pwm.setPWM(ROLL_PIN_2, 0, rollPos2);
}

void homePosition() {
  panPos     = 270;
  tiltPos    = 150;
  rollPos    = 150;
  crunchPos  = 90;
  tiltPos2   = 150;
  rollPos2   = 150;

panPos     = constrain(panPos, SERVOMIN_PAN, SERVOMAX_PAN);
  tiltPos    = constrain(tiltPos, SERVOMIN_TILT, SERVOMAX_TILT);
  rollPos    = constrain(rollPos, SERVOMIN_ROLL, SERVOMAX_ROLL);
  crunchPos  = constrain(crunchPos, SERVOMIN_CRUNCH, SERVOMAX_CRUNCH);
  tiltPos2   = constrain(tiltPos2, SERVOMIN_TILT_2, SERVOMAX_TILT_2);
  rollPos2   = constrain(rollPos2, SERVOMIN_ROLL_2, SERVOMAX_ROLL_2);

setAllServos();
}

void setServoPulse(uint8_t n, double pulse) {
  double pulselength = 1000000.0 / SERVO_FREQ;
  pulselength /= 4096.0;
  pulse *= 1000000.0;
  pulse /= pulselength;

pwm.setPWM(n, 0, (uint16_t)pulse);
}

void printHelp() {
  Serial.println();
  Serial.println("===== Servo Control Commands =====");
  Serial.println("a / d  = Pan left / right");
  Serial.println("r / f  = Tilt 1 up / down");
  Serial.println("q / e  = Roll 1 direction A / B");
  Serial.println("w / s  = Crunch or gripper close / open");
  Serial.println("t / g  = Tilt 2 up / down");
  Serial.println("y / h  = Roll 2 direction A / B");
  Serial.println("x      = Home position");
  Serial.println("p      = Print servo positions");
  Serial.println("?      = Show command list");
  Serial.println("==================================");
  Serial.println();
}

void printPositions() {
  Serial.println();
  Serial.println("Current Servo Positions:");
  Serial.print("panPos     = "); Serial.println(panPos);
  Serial.print("tiltPos    = "); Serial.println(tiltPos);
  Serial.print("rollPos    = "); Serial.println(rollPos);
  Serial.print("crunchPos  = "); Serial.println(crunchPos);
  Serial.print("tiltPos2   = "); Serial.println(tiltPos2);
  Serial.print("rollPos2   = "); Serial.println(rollPos2);
  Serial.println();
}